C***************************************************************C
      SUBROUTINE ALKAT2(PTE, PCF, KNCF, PRC, KERMSG)
C***************************************************************C
C*    EXCITATION RATE COEFFICIENTS BY KATO (TYPE = 2)          *C
C*            +    +    +    +    +    +    +    +             *C
C*        PTE    : ELECTRON TEMPERATURE (EV)                   *C
C*        PRC    : RATE COEFFICIENT (CM[3]/SEC)                *C
C*        KERMSG : ERROR MESSAGE                               *C
C*            +    +    +    +    +    +    +    +             *C
C*        PCF(1)         =  EIJ : THRESHOLD ENERGY             *C
C*        PCF(2)         =  GI  : STATISTICAL WEIGHT           *C
C*        PCF(3)-(8)     =  A-F : COEFFICIENTS OF FITTING      *C
C*        PCF(9)-(11)    =  P,Q,X1 : RESONANCE                 *C
C*            +    +    +    +    +    +    +    +             *C
C*                                     BY T. KATO              *C
C*            +    +    +    +    +    +    +    +             *C
C*        MODIFIED FROM SUBROUTINE RATEN                       *C
C*            OCT.11, 1990             BY K. TAKASUGI          *C
C***************************************************************C
C--- EXCITATION RATE COEFFICIENT FROM IPPJ-AM-27 -------
c     SUBROUTINE RATE27(TEMP,EIJ,GI,ITYPE,A,B,C,D,E,F,CRATE)
C
      IMPLICIT REAL*8 (A-H,O-Z)
      DIMENSION PCF(11)
      CHARACTER*(*) KERMSG
C
        KERMSG=' '
        CONST=8.010E-8/(SQRT(PTE)*PCF(2))
        Y=PCF(1)/PTE
C
      RA=PCF(3)*(1.-EIEXP(Y)*Y)
      RB=PCF(4)*EXP(-PCF(8))/(PCF(8)+Y)
     & + PCF(5)*EXP(-2.*PCF(8))/(2.*PCF(8)+Y)
     & + PCF(6)*EXP(-3.*PCF(8))/(3.*PCF(8)+Y)
     & + PCF(7)*EXP(-4.*PCF(8))/(4.*PCF(8)+Y)
      PRC=CONST*EXP(-Y)*Y*(RA+RB)
C
      if(KNCF .gt. 8) then
        RRES=CONST*EXP(-Y)
     &      *(PCF(9)*(1.+1./Y)*(1.-EXP((1.-PCF(11))*Y)
     &        *(PCF(11)+1./Y)/(1.+1./Y))
     &      + PCF(10)*(1.-EXP((1.-PCF(11))*Y)))
        PRC=PRC + RRES
      endif
C
      RETURN
      END
C