C***************************************************************C
      SUBROUTINE ALLOTZ(PE, PCF, KNCF, PXS, KERMSG)
C***************************************************************C
C*    IONIZATION CROSS SECTION BY LOTZ (I)                     *C
C*            +    +    +    +    +    +    +    +             *C
C*        PE     : ELECTRON ENERGY (EV)                        *C
C*        KNCF   : NUMBER OF COEFFICIENTS SUPPLIED IN PCF      *C
C*        PXS    : CROSS SECTION (CM[2])                       *C
C*        KERMSG : ERROR MESSAGE                               *C
C*            +    +    +    +    +    +    +    +             *C
C*        PCF(1)(6)(11)  = RKAI : IONIZATION POTENTIAL         *C
C*        PCF(2)(7)(12)  = GZAI : NUMBER OF ELECTRONS          *C
C*        PCF(3)(8)(13)  =  AA  : COEFFICIENT A                *C
C*        PCF(4)(9)(14)  =  BB  :             B                *C
C*        PCF(5)(10)(15) =  CC  :             C                *C
C*            +    +    +    +    +    +    +    +             *C
C*                                     BY T. KATO              *C
C*            +    +    +    +    +    +    +    +             *C
C*        MODIFIED FROM FUNCTION CRSION                        *C
C*            FEB.17, 1990             BY K. TAKASUGI          *C
C***************************************************************C
C
      IMPLICIT REAL*8 (A-H,O-Z)
      DIMENSION PCF(15)
      CHARACTER*(*) KERMSG
C
      IF(PE.LE.1.0E-10) THEN
        PXS=0.0
        KERMSG=' ALLOTZ: ENERGY BELOW 1.0E-10 EV'
        RETURN
      ELSE IF(KNCF .NE. 15) THEN
        KERMSG = ' ALLOTZ: INCORRECT NUMBER OF COEFFICIENTS'
        RETURN
      ELSE
        KERMSG = ' '
      ENDIF
C
   10 CONTINUE
        SST=0.0
      DO 20 J=1,3
        DPOT=PCF(5*J-4)
        DGZAI=PCF(5*J-3)
        DA=PCF(5*J-2)
        DB=PCF(5*J-1)
        DC=PCF(5*J)
      IF(PE.GT.DPOT. AND .DPOT.GT.0.) THEN
        X1=PE/DPOT
        SS1=1.-DB*EXP(-DC*(X1-1.))
        SST=DA*DGZAI*LOG(X1)*SS1/(PE*DPOT)+SST
      ENDIF
   20 CONTINUE
        PXS=SST*1.0E-14
      RETURN
      END
C